Restar fechas en Excel

Para restar dos fechas en Excel basta con una resta simple, que da el resultado en días, pero si lo necesitamos en meses, en años o en la forma «1 año, 8 meses y 16 días», hay que recurrir a la función SIFECHA. Excel también permite la operación contraria: restarle días, meses o años a una fecha. ¿Qué fórmula usar en cada caso y por qué a veces el resultado sale como una fecha o como un número negativo?

Cómo maneja Excel las fechas.

Para entender la resta conviene saber que Excel guarda cada fecha como un número: la cantidad de días transcurridos desde el 1 de enero de 1900. Así, el 1 de enero de 2026 es para Excel el número 46023, y lo que vemos como fecha es solo el formato de la celda.

Por eso restar dos fechas es simplemente restar dos números, y el resultado son los días que hay entre ellas. Y por eso también la resta solo funciona si Excel reconoce las celdas como fechas: si la fecha llegó como texto, el resultado será el error #¡VALOR!, y hay que convertirla primero, como explicamos en el artículo sobre qué hacer cuando

• Guía de arrendamiento sin riesgo
• Liquidador de intereses judiciales y comerciales
• Liquidador de intereses propiedad horizontal

Restar dos fechas para obtener los días.

Supongamos que en A2 está la fecha inicial, 10/01/2020, y en B2 la fecha final, 26/09/2021. En C2 escribimos:

=B2-A2

El resultado es 625 días. La fecha más reciente va primero, porque si invertimos el orden el resultado será −625: el número de días es correcto, pero con signo negativo. Si no sabemos cuál de las dos fechas es la mayor, la función ABS devuelve siempre el valor positivo: =ABS(B2-A2).

Si el resultado aparece como una fecha.

Es frecuente que Excel muestre el resultado como 16/09/1901 en lugar de 625. No es un error de cálculo: Excel le aplicó a la celda el formato de fecha de las celdas restadas. Se corrige seleccionando la celda y, en la pestaña «Inicio», cambiando el formato a «General» o «Número».

Incluir o no el primer día.

La resta no cuenta el día inicial: entre el 1 y el 30 de octubre arroja 29 días. Si el cálculo debe incluir ambos extremos, como ocurre con muchos plazos, se suma 1. Este punto, junto con la función DIAS y los días transcurridos hasta hoy, se desarrolla en el artículo sobre cómo calcular los días entre dos fechas en Excel.

Restar fechas para obtener meses o años.

Cuando el resultado debe expresarse en meses o en años, la resta simple no sirve, porque los meses no tienen todos los mismos días. Para eso existe la función SIFECHA:

=SIFECHA(fecha_inicial;fecha_final;"unidad")

La fecha inicial siempre va primero; si es posterior a la final, la función devuelve el error #¡NUM!. La función no aparece en el asistente ni en el autocompletado de Excel, porque Microsoft la conserva solo por compatibilidad, pero funciona en todas las versiones si se escribe completa.

El tercer argumento indica qué queremos medir:

Con las mismas fechas del ejemplo, 10/01/2020 y 26/09/2021, los resultados son estos:

Lo importante es que SIFECHA cuenta unidades completas: entre el 10 de enero de 2020 y el 26 de septiembre de 2021 hay 20 meses completos, no 21, porque el mes número 21 se completaría el 10 de octubre.

Por qué no conviene restar los años o los meses directamente.

Una fórmula que se ve con frecuencia para calcular los meses es restar los años, multiplicarlos por doce y sumar la diferencia de meses:

=(AÑO(B2)-AÑO(A2))*12+MES(B2)-MES(A2)

El problema es que esa fórmula no cuenta meses transcurridos, sino cambios de mes en el calendario. Entre el 31 de enero y el 1 de febrero devuelve 1 mes, aunque solo pasó un día. Lo mismo ocurre con =AÑO(B2)-AÑO(A2), que entre el 31 de diciembre de 2025 y el 1 de enero de 2026 devuelve 1 año.

Para meses y años transcurridos, que es lo que casi siempre se necesita en plazos, antigüedad o vencimientos, la función correcta es SIFECHA. El cálculo de meses, incluidas las fracciones de mes, se amplía en el artículo sobre la fórmula para calcular los meses entre fechas.

Restar fechas para obtener años, meses y días.

Cuando el resultado debe expresarse completo, por ejemplo para indicar la antigüedad de un trabajador o el tiempo de un contrato, combinamos varias unidades de SIFECHA con el operador &:

=SIFECHA(A2;B2;"y")&" años, "&SIFECHA(A2;B2;"ym")&" meses y "&SIFECHA(A2;B2;"md")&" días"

Con las fechas del ejemplo, el resultado es «1 años, 8 meses y 16 días». Para que diga «1 año» en singular se puede agregar una condición, aunque en la mayoría de informes basta con la fórmula anterior.

Una precaución con los días sobrantes.

Microsoft advierte que la unidad «md» puede devolver resultados incorrectos en algunos casos, en particular cuando la fecha inicial cae en los últimos días de un mes más largo que el mes final. Para obtener los días sobrantes de forma segura, se restan a la fecha final los meses completos ya contados:

=B2-FECHA.MES(A2;SIFECHA(A2;B2;"m"))

La función FECHA.MES suma a la fecha inicial los 20 meses completos, lo que da el 10 de septiembre de 2021, y la resta frente al 26 de septiembre arroja los mismos 16 días. La fórmula completa, con esta corrección, es:

=SIFECHA(A2;B2;"y")&" años, "&SIFECHA(A2;B2;"ym")&" meses y "&(B2-FECHA.MES(A2;SIFECHA(A2;B2;"m")))&" días"

El mismo cálculo aplicado a la fecha de nacimiento se explica en el artículo sobre la fórmula para calcular la edad en Excel.

Restar días, meses o años a una fecha.

La otra operación frecuente es partir de una fecha y retroceder un plazo, por ejemplo, para saber desde cuándo se cuentan los últimos seis meses de salario o qué fecha era 30 días antes de un vencimiento.

Restar días.

Como las fechas son números de días, basta con restar el número de días:

=A2-30

Si A2 contiene el 15/11/2026, el resultado es el 16/10/2026. Si los días que hay que restar son hábiles, la función es otra y se explica en el artículo sobre cómo sumar días a una fecha en Excel, donde se usan valores negativos para retroceder.

Restar meses.

Para restar meses usamos la función FECHA.MES con un número negativo:

=FECHA.MES(A2;-3)

Si A2 contiene el 31/05/2026, el resultado es el 28/02/2026. FECHA.MES ajusta automáticamente el día cuando el mes de destino es más corto: como febrero no tiene 31 días, devuelve su último día. Por eso es preferible a la fórmula =FECHA(AÑO(A2);MES(A2)-3;DIA(A2)), que en ese mismo caso devolvería el 3 de marzo.

Restar años.

Los años se restan con la misma función, multiplicando por doce:

=FECHA.MES(A2;-12*2)

Esta fórmula retrocede dos años. Si la fecha es un 29 de febrero, el resultado es el 28 de febrero del año de destino, salvo que también sea bisiesto.

Errores frecuentes al restar fechas.

Los resultados inesperados casi siempre se deben a una de estas causas:

Si después de revisar el formato el resultado sigue sin tener sentido, conviene verificar que el sistema interprete las fechas en el orden día/mes/año, porque un 05/10 puede leerse como 5 de octubre o como 10 de mayo según la configuración regional del computador.

Descargar el ejemplo en Excel.

El archivo de ejemplo contiene varias parejas de fechas con la resta en días, los meses y años completos con SIFECHA, el resultado en años, meses y días con la fórmula corregida, y una hoja para restar días, meses y años a una fecha. Descargar archivo.

A continuación respondemos las preguntas frecuentes de nuestros lectores.

• Calculadora de retención en la fuente por salarios
• Liquidador de renta personas naturales
• Proyección y planeación pensional
• Guía de propiedad horizontal
• Guía Laboral 2026
• Liquidador de pensiones en Colpensiones