Fórmula en Excel para calcular los meses entre dos fechas

Para saber cuántos meses hay entre dos fechas en Excel se usa la función SIFECHA, que cuenta los meses completos. Pero «meses entre dos fechas» puede significar cosas distintas: meses completos, meses con fracción, meses calendario que abarca un periodo o meses y días. ¿Qué fórmula corresponde a cada caso y cómo se suman meses a una fecha para calcular un vencimiento?

Meses completos entre dos fechas con SIFECHA.

Con la fecha inicial en A1 y la final en B1, la fórmula es:

=SIFECHA(A1;B1;"m")

El tercer argumento, "m", le indica a Excel que cuente meses. La fecha inicial debe ir primero: si la final es anterior, SIFECHA devuelve el error #¡NUM!.

SIFECHA no aparece en el asistente de funciones ni en el autocompletado de Excel, porque es una función heredada de otras hojas de cálculo. Hay que escribirla completa, pero funciona en todas las versiones.

Cuándo se completa un mes.

SIFECHA solo cuenta los meses completos: un mes se completa cuando se llega al mismo número de día del mes siguiente. Supongamos estas fechas:

Del 1 de enero al 31 de octubre hay 10 meses si se cuentan ambos días, pero SIFECHA da 9, porque el décimo mes se completa el 1 de noviembre. Cuando el último día también debe contarse, como en un contrato que va del 1 de enero al 31 de octubre, se suma un día a la fecha final:

=SIFECHA(A1;B1+1;"m")

Con esa fórmula, el segundo ejemplo da 10 meses.

Meses con fracción.

Si necesitamos saber que entre dos fechas han pasado, por ejemplo, 4,8 meses y no solo 4, hay que partir de los días transcurridos y dividirlos entre la duración de un mes. Hay tres formas de hacerlo, y dan resultados un poco distintos.

Dividir los días entre 30.

Restando las dos fechas se obtienen los días, que se dividen entre 30:

=(B1-A1)/30

Es la forma más simple, pero sobrestima los meses, porque la mayoría de los meses tienen 31 días.

La resta de fechas para obtener días se explica en el artículo sobre cómo restar fechas en Excel.

Dividir los días entre la duración promedio del mes.

Un año tiene en promedio 365 ÷ 12 = 30,42 días por mes. Dividir entre ese valor da un resultado más cercano a la realidad:

=(B1-A1)/(365/12)

Esta opción reparte los días del año por igual entre los doce meses, de modo que no sobrestima ni subestima los meses cortos o largos.

Meses con base de 360 días.

En materia laboral y financiera es común contar los meses de 30 días y el año de 360. La función FRAC.AÑO devuelve la fracción de año entre dos fechas con esa base, y multiplicada por 12 da los meses:

=FRAC.AÑO(A1;B1)*12

Sin el tercer argumento, FRAC.AÑO usa la base 30/360. Si se escribe 1 como tercer argumento, usa los días reales.

Con las fechas 15/01/2026 y 10/06/2026, las tres fórmulas dan 4,87, 4,80 y 4,83 meses. La elección depende del uso: para intereses o prestaciones se suele usar la base 360; para estadísticas, el promedio de 30,42 días.

Meses calendario que abarca un periodo.

A veces la pregunta no es cuántos meses pasaron sino en cuántos meses distintos cae un periodo, por ejemplo para saber cuántos meses de nómina o de declaraciones hay que revisar. Del 15 de enero al 10 de junio se tocan seis meses (enero a junio), aunque solo hayan pasado cuatro completos:

=(AÑO(B1)-AÑO(A1))*12+MES(B1)-MES(A1)+1

La fórmula convierte la diferencia de años en meses, le suma la diferencia de meses y agrega uno para contar el mes inicial. No tiene en cuenta los días.

Meses y días entre dos fechas.

Para expresar el resultado como «4 meses y 26 días», se calculan los meses completos con SIFECHA y los días que sobran restando a la fecha final la fecha que resulta de sumar esos meses a la inicial:

=SIFECHA(A1;B1;"m")&" meses y "&(B1-FECHA.MES(A1;SIFECHA(A1;B1;"m")))&" días"

Con 15/01/2026 y 10/06/2026, el resultado es «4 meses y 26 días»: del 15 de enero al 15 de mayo hay 4 meses, y del 15 de mayo al 10 de junio, 26 días.

No sirve restar el día de una fecha del día de la otra, como en DIA(B1)-DIA(A1), porque cuando el día final es menor que el inicial el resultado es negativo: con estas mismas fechas daría −5. Si además se necesitan los años, la fórmula para obtener años, meses y días está en el artículo sobre restar fechas en Excel.

Sumar o restar meses a una fecha.

La función FECHA.MES suma a una fecha el número de meses que se le indique, y los resta si el número es negativo:

=FECHA.MES(A1;3)

=FECHA.MES(A1;-3)

Si el resultado aparece como un número, basta con darle formato de fecha a la celda.

Por qué no conviene usar FECHA(AÑO;MES+n;DIA).

Otra forma de sumar meses es armar la fecha con FECHA(AÑO(A1);MES(A1)+3;DIA(A1)). Funciona en la mayoría de los casos, pero falla con los últimos días del mes:

Como febrero no tiene día 31, FECHA traslada los días sobrantes a marzo. FECHA.MES, en cambio, se detiene en el último día del mes. Si lo que se necesita es el último día del mes resultante, se usa FIN.MES(A1;3).

Calcular el vencimiento de un plazo en meses.

Sumar meses es especialmente útil para controlar plazos legales. La forma de contarlos la fija el artículo 59 de la ley 4 de 1913, Código de Régimen Político y Municipal:

«Todos los plazos de días, meses o años de que se haga mención legal, se entenderán que terminan a la medianoche del último día del plazo. Por año y por mes se entienden los del calendario común, y por día el espacio de veinticuatro horas; pero en la ejecución de las penas se estará a lo que disponga la ley penal.»

Y cuando el último día no es hábil, el artículo 62 de la misma ley dispone:

«En los plazos de días que se señalen en las leyes y actos oficiales, se entienden suprimidos los feriados y de vacantes, a menos de expresarse lo contrario. Los de meses y años se computan según el calendario; pero si el último día fuere feriado o de vacante, se extenderá el plazo hasta el primer día hábil.»

Esto significa que un plazo en meses vence el mismo número de día del mes final, que es justamente lo que calcula FECHA.MES, y que si ese día es festivo o no hay atención, el plazo se corre al siguiente día hábil.

Ejemplo con el requerimiento especial de la DIAN.

El plazo para responder un requerimiento especial lo fija el artículo 707 del Estatuto Tributario, que en lo pertinente establece:

«Dentro de los tres (3) meses siguientes, contados a partir de la fecha de notificación del requerimiento especial, el contribuyente, responsable, agente retenedor o declarante, deberá formular por escrito sus objeciones…»

Supongamos que el requerimiento se notifica el 22 de octubre de 2026. Con =FECHA.MES(A1;3) el plazo vence el viernes 22 de enero de 2027, que es día hábil.

Ahora supongamos que se notifica el 8 de septiembre de 2026. Tres meses después es el 8 de diciembre de 2026, festivo de la Inmaculada Concepción, de modo que el plazo se extiende al miércoles 9 de diciembre. Para que Excel haga ese ajuste, se combina FECHA.MES con DIA.LAB.INTL:

=DIA.LAB.INTL(FECHA.MES(A1;3)-1;1;1;Festivos)

La fórmula se ubica un día antes del vencimiento y avanza un día hábil: si el vencimiento es hábil, lo devuelve tal cual; si no, salta al siguiente día hábil. El código 1 excluye sábados y domingos, días en que la DIAN no presta atención, y «Festivos» es el rango con la lista de festivos. La función y sus códigos se explican en el artículo sobre cómo sumar días hábiles a una fecha en Excel.

Recordemos que el resultado es el último día del plazo, y que la respuesta puede presentarse hasta ese día.

Descargar el ejemplo en Excel.

El archivo tiene tres hojas: «Meses entre fechas», con las fórmulas de meses completos, con fracción, meses calendario y meses y días aplicadas a varios pares de fechas; «Sumar meses», con la comparación entre FECHA.MES y FECHA, y «Plazos en meses», que calcula el vencimiento y lo ajusta al día hábil con la lista de festivos de Colombia de 2026 y 202. Descargar archivo.

A continuación respondemos las preguntas frecuentes de nuestros lectores.