Funciones condicionales en Excel: SI, Y, O, SUMAR.SI y CONTAR.SI

Una función condicional es la que hace un cálculo solo cuando se cumple una condición. La principal es SI, que devuelve un resultado si la condición es verdadera y otro si es falsa; con Y y O se combinan varias condiciones, y funciones como SUMAR.SI o CONTAR.SI suman o cuentan solo los datos que cumplen un criterio. ¿Cómo se escribe cada una y cómo se arman las fórmulas con varios rangos de valores?

Qué es una condición en Excel.

Una condición es una comparación cuyo resultado es VERDADERO o FALSO. Se escribe con los operadores de comparación:

Los textos de la comparación van entre comillas y no distinguen mayúsculas de minúsculas: A1="bogotá" es verdadero si A1 dice «Bogotá». Los números van sin comillas y sin puntos de miles: 1000000, no 1.000.000.

Un rango, por su parte, es un conjunto de celdas contiguas que se identifica con la primera y la última celda separadas por dos puntos, como A1:C10. Las funciones condicionales evalúan la condición sobre cada celda de un rango. Los rangos y sus nombres se explican en el artículo sobre qué es un rango en Excel.

• Liquidador de intereses propiedad horizontal
• Guía de arrendamiento sin riesgo
• Proyección y planeación pensional

La función SI.

La función SI tiene tres argumentos: la condición, el resultado si es verdadera y el resultado si es falsa:

=SI(condición;valor_si_verdadero;valor_si_falso)

Supongamos que una comisión del 5 % solo se paga si las ventas de A1 superan 1.000.000:

=SI(A1>1000000;A1*5%;0)

Si A1 es 1.760.000, el resultado es 88.000; si es 950.000, es 0. Los resultados pueden ser números, cálculos, textos entre comillas o una celda vacía (""). Por ejemplo, para que C1 muestre el valor de A1 solo cuando es negativo y quede vacía en los demás casos:

=SI(A1<0;A1;"")

Si A1 contiene −10, C1 muestra −10; si contiene 25, queda vacía.

Varias condiciones con Y y O.

Cuando deben cumplirse varias condiciones a la vez, se usa la función Y dentro de SI; cuando basta con que se cumpla una, la función O. Supongamos que para aprobar un curso los dos parciales deben ser de 70 o más:

=SI(Y(B2>=70;C2>=70);"Aprobado";"Reprobado")

Con 90 y 69, el resultado es «Reprobado», porque el segundo parcial no cumple. Si bastara con aprobar uno de los dos, se usaría O:

=SI(O(B2>=70;C2>=70);"Aprobado";"Reprobado")

Con 90 y 69, ahora el resultado es «Aprobado». La función NO invierte una condición: =SI(NO(A1="Bogotá");…) se cumple para cualquier ciudad distinta de Bogotá.

Un valor dentro de un rango.

Para comprobar que un valor está entre dos límites, se combinan dos condiciones con Y. Que A1 esté entre 500 y 1.000, incluidos ambos:

=SI(Y(A1>=500;A1<=1000);"Dentro del rango";"Fuera del rango")

Si los límites no deben incluirse, se usan > y < en lugar de >= y <=. La misma comprobación puede escribirse con dos SI anidados, =SI(A1>=500;SI(A1<=1000;"X";"");""), pero con Y es más clara.

Un ejemplo con varias condiciones: la obligación de declarar renta.

Una persona natural no está obligada a declarar renta si cumple todas las condiciones de los artículos 592, 593 y 594-3 del Estatuto Tributario, entre ellas que sus ingresos brutos sean inferiores a 1.400 UVT y que su patrimonio bruto no exceda 4.500 UVT, y que sus consumos con tarjeta de crédito, sus compras y consumos y sus consignaciones no excedan 1.400 UVT cada uno. Con los valores del contribuyente en B2:B6 y los topes en C2:C6:

=SI(Y(B2<C2;B3<=C3;B4<=C4;B5<=C5;B6<=C6);"No obligado";"Obligado a declarar")

Basta con que una condición no se cumpla para que la persona esté obligada. Los topes en pesos dependen del valor de la UVT del año gravable, y hay otras condiciones, como la responsabilidad del IVA; el detalle está en el artículo sobre quiénes están obligados a declarar renta.

SI anidados para varios rangos de valores.

Cuando hay más de dos resultados posibles, como una tabla de comisiones por niveles de venta, se anidan varias funciones SI: el valor si es falso de una es otra función SI. Supongamos esta política:

La fórmula evalúa los niveles de mayor a menor:

=A2*SI(A2>=5000000;15%;SI(A2>=2000000;10%;SI(A2>=1000000;5%;0)))

El orden es importante. Excel evalúa las condiciones de izquierda a derecha y se detiene en la primera que se cumple; si se empezara por A2>=1000000, una venta de 7.000.000 quedaría con el 5 %, porque esa condición ya es verdadera. Al ir de mayor a menor, cada nivel solo se alcanza si no se cumplió el anterior.

También importa usar >= y no > cuando la política dice «desde»: con > una venta de exactamente 5.000.000 quedaría en el nivel inferior.

SI.CONJUNTO.

En Excel 2019 y Microsoft 365, la función SI.CONJUNTO evita anidar: recibe pares de condición y resultado, y devuelve el del primer par que se cumpla:

=SI.CONJUNTO(A2>=5000000;15%;A2>=2000000;10%;A2>=1000000;5%;VERDADERO;0)

El último par, VERDADERO;0, funciona como «en cualquier otro caso».

Una tabla en lugar de SI anidados.

Cuando los niveles son muchos o cambian con frecuencia, es más práctico escribirlos en una tabla, ordenada de menor a mayor por el límite inferior, y buscar con BUSCARV en modo aproximado:

=BUSCARV(A2;$H$2:$I$5;2;VERDADERO)

Con VERDADERO como último argumento, BUSCARV busca el mayor límite que sea menor o igual al valor y devuelve el porcentaje de esa fila. Si cambia la política, se modifica la tabla y no la fórmula.

Así se resuelven también las tablas progresivas, como la de retención en la fuente por pagos laborales del artículo 383 del Estatuto Tributario, que en el archivo descargable se calcula de las dos formas. Como la norma dice «más de 95 hasta 150», en un valor exacto de un límite BUSCARV lo ubica en el tramo siguiente, lo que conviene tener presente. Las comisiones con otras condiciones se desarrollan en el artículo sobre las comisiones por ventas condicionadas en Excel.

Funciones condicionales de suma y conteo.

Excel tiene funciones que aplican una condición sobre un rango y suman, cuentan o promedian solo los datos que la cumplen. Se reconocen por el .SI en su nombre:

Supongamos una tabla de ventas con el vendedor en A2:A11, la ciudad en B2:B11 y el valor en C2:C11. Para sumar las ventas de Pedro:

=SUMAR.SI(A2:A11;"Pedro";C2:C11)

El primer argumento es el rango donde se evalúa el criterio, el segundo el criterio y el tercero el rango que se suma. Y para sumar las ventas de Pedro en Bogotá, con dos criterios:

=SUMAR.SI.CONJUNTO(C2:C11;A2:A11;"Pedro";B2:B11;"Bogotá")

En las funciones .CONJUNTO el rango que se suma va primero, seguido de los pares de rango y criterio.

Criterios con operadores y con celdas.

Cuando el criterio incluye un operador, va entre comillas: para contar las ventas superiores a 1.000.000, =CONTAR.SI(C2:C11;">1000000"). Si el valor está en una celda, por ejemplo en H2, el operador se escribe entre comillas y se une a la celda con &:

=CONTAR.SI(C2:C11;">"&H2)

Escribirlo como ">H2" no funciona, porque Excel buscaría el texto H2, y escribirlo sin comillas, como >H2, da un error de fórmula.

Descargar el ejemplo en Excel.

El archivo tiene cuatro hojas: «SI, Y, O», con el ejemplo de los parciales y el de los valores negativos; «Comisiones (anidadas)», que calcula la comisión con SI anidados, SI.CONJUNTO y BUSCARV para comparar; «CONTAR.SI y SUMAR.SI», con criterios escritos en celdas, y «Tabla progresiva», con la tabla del artículo 383 del E.T. calculada con BUSCARV y con SI anidados. Descargar archivo.

A continuación respondemos las preguntas frecuentes de nuestros lectores.

• Liquidador de renta personas naturales
• Calculadora de retención en la fuente por salarios
• Liquidador de intereses judiciales y comerciales
• Guía Laboral 2026
• Guía de propiedad horizontal
• Liquidador de pensiones en Colpensiones