Fórmulas para contar caracteres y palabras en Excel

Para contar cuántos caracteres hay en una celda de Excel se usa la función LARGO, y combinada con SUSTITUIR y ESPACIOS sirve también para contar las palabras, contar cuántas veces aparece una letra o excluir los espacios. Para un rango de celdas no hace falta una macro: basta con SUMAPRODUCTO. ¿Cómo se escribe cada fórmula?

Contar los caracteres de una celda.

La función LARGO devuelve el número de caracteres de un texto. Con el texto en A1:

=LARGO(A1)

Si A1 contiene «Derecho laboral en Colombia», el resultado es 27. LARGO cuenta todo: letras, números, signos, tildes y también los espacios, incluidos los que haya al principio o al final del texto.

Cuando la celda contiene un número, LARGO cuenta los dígitos del valor y no lo que muestra el formato: si A1 tiene 1250000 con formato de miles, que se ve como 1.250.000, el resultado es 7, porque los puntos no hacen parte del valor.

• Liquidador de intereses propiedad horizontal
• Guía de propiedad horizontal
• Proyección y planeación pensional

Contar los caracteres sin espacios.

Para no contar los espacios, se eliminan con SUSTITUIR antes de medir el texto:

=LARGO(SUSTITUIR(A1;" ";""))

Con el mismo texto, el resultado es 24, porque hay tres espacios. Si solo se quieren quitar los espacios sobrantes del principio, del final y los dobles, pero no los que separan las palabras, se usa ESPACIOS: =LARGO(ESPACIOS(A1)).

Contar cuántas veces aparece un carácter.

Para saber cuántas veces aparece una letra o un signo, se compara el largo del texto con el largo que queda después de eliminar ese carácter:

=LARGO(A1)-LARGO(SUSTITUIR(A1;"a";""))

SUSTITUIR distingue mayúsculas de minúsculas, de modo que esa fórmula no cuenta la «A» mayúscula. Para contar ambas, se pasa el texto a minúsculas con MINUSC: =LARGO(A1)-LARGO(SUSTITUIR(MINUSC(A1);"a";"")). Las letras con tilde, como «á», son caracteres distintos y se cuentan aparte.

La misma fórmula sirve para contar cuántas veces aparece una palabra, dividiendo el resultado entre el largo de la palabra, porque cada aparición elimina varios caracteres:

=(LARGO(A1)-LARGO(SUSTITUIR(MINUSC(A1);"pago";"")))/LARGO("pago")

Si A1 contiene «pago de nómina y pago de prima», el resultado es 2.

Contar los caracteres de un rango.

Para contar todos los caracteres de un rango de celdas, como A1:C50, no se necesita una macro. SUMAPRODUCTO aplica LARGO a cada celda del rango y suma los resultados:

=SUMAPRODUCTO(LARGO(A1:C50))

Y sin contar los espacios:

=SUMAPRODUCTO(LARGO(SUSTITUIR(A1:C50;" ";"")))

En Microsoft 365 también funciona =SUMA(LARGO(A1:C50)), porque esa versión calcula matrices de forma automática.

Contar las palabras de una celda.

Excel no tiene una función para contar palabras, pero se pueden contar los espacios que las separan y sumar uno: tres espacios separan cuatro palabras. La fórmula más simple es esta:

=LARGO(A1)-LARGO(SUSTITUIR(A1;" ";""))+1

Funciona solo si cada palabra está separada por un único espacio y no hay espacios al principio ni al final. Con un texto como «  espacios   de   más  », que tiene espacios de sobra, la fórmula simple da 11 cuando en realidad son 3 palabras, y con una celda vacía da 1.

Fórmula que tolera los espacios de más.

Para evitar esos errores, primero se limpia el texto con ESPACIOS, que quita los espacios del principio y del final y reduce a uno los dobles, y se controla el caso de la celda vacía:

=SI(LARGO(ESPACIOS(A1))=0;0;LARGO(ESPACIOS(A1))-LARGO(SUSTITUIR(ESPACIOS(A1);" ";""))+1)

Con el texto de espacios de más el resultado es 3, y con una celda vacía, 0. El funcionamiento de ESPACIOS, incluido el espacio duro que no elimina, se explica en el artículo sobre cómo quitar los espacios en blanco en Excel.

Contar las palabras de un rango.

Para el total de palabras de varias celdas, lo más práctico es calcular las palabras de cada celda en una columna auxiliar con la fórmula anterior y sumarla. También puede hacerse en una sola fórmula con SUMAPRODUCTO, aplicando la misma lógica a todo el rango.

Contar celdas con texto.

A veces lo que se busca no es contar caracteres sino cuántas celdas de un rango contienen texto. Para eso se usa CONTAR.SI con el comodín asterisco:

=CONTAR.SI(A1:A100;"*")

El asterisco representa cualquier texto, de modo que la fórmula cuenta las celdas con texto y no cuenta las que tienen números ni las vacías. Para contar todas las celdas no vacías, con texto o con números, se usa CONTARA.

Limitar el número de caracteres de una celda.

Cuando se diligencian formatos con un máximo de caracteres, como una descripción que se cargará a otro sistema, se puede impedir que se supere el límite con la validación de datos: se seleccionan las celdas, se elige «Datos», «Validación de datos», en «Permitir» se escoge «Longitud del texto», y se fija el máximo.

Una celda de Excel admite como máximo 32.767 caracteres.

Descargar el ejemplo en Excel.

El archivo aplica a varios textos las fórmulas del artículo: caracteres con y sin espacios, veces que aparece una letra o palabra que se elige en una celda, palabras con la fórmula simple y con la que tolera los espacios de más, totales del rango con SUMAPRODUCTO y conteo de celdas con texto. Descargar archivo.

A continuación respondemos las preguntas frecuentes de nuestros lectores.

• Liquidador de pensiones en Colpensiones
• Guía de arrendamiento sin riesgo
• Liquidador de renta personas naturales
• Guía Laboral 2026
• Calculadora de retención en la fuente por salarios
• Liquidador de intereses judiciales y comerciales