Fórmula para unir nombres y apellidos en Excel

Cuando los nombres y apellidos están en columnas separadas, Excel permite unirlos en una sola celda con el operador &, con la función CONCATENAR o, en las versiones recientes, con UNIRCADENAS, que además omite las celdas vacías. La clave está en agregar los espacios entre cada parte. ¿Qué fórmula usar y cómo evitar los espacios dobles cuando falta un segundo nombre o un segundo apellido?

Unir nombres y apellidos con el operador &.

Es la forma más sencilla y funciona en cualquier versión de Excel. Supongamos esta tabla, con los datos desde la fila 2:

Para unir el primer nombre y el primer apellido en la celda E2 escribimos:

=A2&" "&C2

El resultado es «Pedro Calderón». El símbolo & une los textos, y las comillas con un espacio en medio (" ") agregan la separación entre una palabra y otra; sin ellas, el resultado sería «PedroCalderón».

Para el nombre completo, con las cuatro partes, la fórmula es:

=A2&" "&B2&" "&C2&" "&D2

Luego copiamos la fórmula hacia abajo, arrastrando el cuadro de la esquina inferior derecha de la celda o dando doble clic sobre él.

• Guía Laboral 2026
• Calculadora de retención en la fuente por salarios
• Liquidador de intereses propiedad horizontal

Unir nombres y apellidos con CONCATENAR.

La función CONCATENAR hace exactamente lo mismo que el operador &, pero con los elementos separados por punto y coma:

=CONCATENAR(A2;" ";B2;" ";C2;" ";D2)

El resultado es idéntico. En las versiones recientes, Excel la reemplazó por CONCAT, que se escribe igual pero además acepta rangos completos. CONCATENAR se mantiene por compatibilidad, de modo que cualquiera de las dos sirve.

Si su computador usa la coma como separador de argumentos, las fórmulas se escriben con comas en lugar de punto y coma. Depende de la configuración regional de Windows, no de la versión de Excel.

El problema de los espacios dobles.

Las fórmulas anteriores tienen un inconveniente cuando falta alguna parte del nombre. En el segundo registro, Martha no tiene segundo nombre, y la fórmula produce «Martha  Puentes Daza», con dos espacios seguidos; en el tercero, Andrés no tiene segundo apellido, y el resultado termina en un espacio sobrante.

El error no se nota a simple vista, pero causa problemas al buscar, cruzar bases de datos o cargar la información en un aplicativo. Hay dos formas de evitarlo.

Con UNIRCADENAS.

La función UNIRCADENAS, disponible en Excel 2019 y Microsoft 365, une un rango con el separador que le indiquemos y puede ignorar las celdas vacías:

=UNIRCADENAS(" ";VERDADERO;A2:D2)

El primer argumento es el separador, en este caso un espacio; el segundo, VERDADERO, le indica que omita las celdas vacías, y el tercero es el rango con las partes del nombre. El resultado es «Martha Puentes Daza», sin espacios de más.

Con ESPACIOS, en versiones anteriores.

Si la versión de Excel no tiene UNIRCADENAS, envolvemos la fórmula en la función ESPACIOS, que elimina los espacios al inicio y al final y reduce a uno los espacios repetidos:

=ESPACIOS(A2&" "&B2&" "&C2&" "&D2)

El resultado es el mismo. La función ESPACIOS y otras formas de limpiar textos se explican en el artículo sobre cómo quitar espacios en Excel.

Poner primero los apellidos.

En listados de nómina, de afiliados o de estudiantes es común que el nombre completo empiece por los apellidos. Basta con cambiar el orden de las celdas dentro de la fórmula:

=ESPACIOS(C2&" "&D2&" "&A2&" "&B2)

El resultado es «Calderón Suárez Pedro José». Si queremos separar los apellidos del nombre con una coma, como se acostumbra en los directorios:

=ESPACIOS(C2&" "&D2)&", "&ESPACIOS(A2&" "&B2)

Y obtenemos «Calderón Suárez, Pedro José».

Corregir mayúsculas y minúsculas al unir.

Cuando los datos vienen escritos de forma desigual, por ejemplo «PEDRO» o «calderón», podemos normalizarlos en la misma fórmula con NOMPROPIO, que deja la primera letra de cada palabra en mayúscula:

=NOMPROPIO(ESPACIOS(A2&" "&B2&" "&C2&" "&D2))

Si el listado debe ir todo en mayúsculas, como lo exigen algunos formularios, usamos MAYUSC en lugar de NOMPROPIO.

Unir nombres y apellidos sin fórmula.

Desde Excel 2013 existe el relleno rápido, que reconoce un patrón a partir de un ejemplo y lo repite en toda la columna, sin escribir fórmulas:

1. En la primera fila de una columna vacía escribimos a mano el resultado que queremos, por ejemplo «Pedro José Calderón Suárez».
2. Nos ubicamos en la celda de abajo.
3. Presionamos Ctrl + E, o vamos a la pestaña «Datos» y damos clic en «Relleno rápido».

Excel completa toda la columna siguiendo el ejemplo. Conviene revisar los resultados, porque el relleno rápido adivina el patrón y puede equivocarse con registros atípicos, y tener presente que no se actualiza si después cambian los datos originales.

Conservar el resultado y borrar las columnas originales.

El resultado de una fórmula depende de las celdas de origen, de modo que si borramos las columnas de nombres y apellidos, la columna unida mostrará el error #¡REF!. Para conservar solo el nombre completo:

1. Seleccionamos la columna con las fórmulas y la copiamos con Ctrl + C.
2. Sobre la misma selección damos clic derecho y elegimos «Pegado especial», opción «Valores».
3. Ahora sí podemos eliminar las columnas originales.

El proceso contrario, dividir un nombre completo en nombres y apellidos, se explica en el artículo sobre la fórmula para separar texto en Excel, y la unión de celdas en general, más allá de los nombres, en el artículo sobre cómo unir celdas en Excel.

Descargar el ejemplo en Excel.

El archivo de ejemplo contiene una lista de nombres con datos incompletos y escritos de forma desigual, y las fórmulas de este artículo aplicadas en columnas separadas, para comparar los resultados. Descargar archivo.

A continuación respondemos las preguntas frecuentes de nuestros lectores.

• Proyección y planeación pensional
• Guía de propiedad horizontal
• Guía de arrendamiento sin riesgo
• Liquidador de renta personas naturales
• Liquidador de intereses judiciales y comerciales
• Liquidador de pensiones en Colpensiones