Cómo poner números consecutivos en Excel con fórmula

Para numerar filas en Excel de forma consecutiva se puede arrastrar el controlador de relleno, pero si se usa una fórmula, la numeración se ajusta sola cuando se agregan o se eliminan datos. La función básica es FILA, y con CONTARA, CONTAR.SI, SUBTOTAL o SECUENCIA se resuelven los casos más comunes: numerar solo las filas con datos, numerar las que cumplen una condición o las que quedan visibles al filtrar. ¿Qué fórmula conviene en cada caso?

Números consecutivos sin fórmula.

Si solo se necesita una numeración fija, no hace falta una fórmula. Hay tres formas rápidas de hacerlo:

• Escribir 1 en la primera celda y 2 en la siguiente, seleccionar ambas y arrastrar hacia abajo el cuadro pequeño de la esquina inferior derecha, llamado controlador de relleno. También sirve hacer doble clic en él, si la columna vecina tiene datos.
• Escribir 1 y arrastrar el controlador de relleno mientras se mantiene presionada la tecla Ctrl.
• Escribir 1, ir a la pestaña «Inicio», «Rellenar», «Series», e indicar el incremento y el valor límite. Es la opción más práctica para series largas, como del 1 al 5.000.

El inconveniente es que esos números son valores fijos: si se elimina o se inserta una fila, la numeración queda con saltos o repetidos y hay que rehacerla.

• Proyección y planeación pensional
• Guía Laboral 2026
• Guía de arrendamiento sin riesgo

Números consecutivos con la función FILA.

La función FILA devuelve el número de fila de una celda. Sin argumentos, devuelve la fila en la que está la fórmula: =FILA() escrita en la fila 5 da 5. Por eso, si la numeración empieza en la fila 5, porque arriba hay títulos y encabezados, se resta 4:

=FILA()-4

Una forma que no depende de dónde empiece la tabla es pedirle a FILA el número de una celda de la primera fila de la hoja. En la primera celda se escribe:

=FILA(A1)

El resultado es 1, y al copiar hacia abajo la referencia cambia a A2, A3, A4, de modo que se obtiene 2, 3, 4. Como la fórmula se recalcula, si se elimina una fila la numeración se corrige sola.

Iniciar la serie en otro número.

Para que la numeración empiece, por ejemplo, en 120, se suma al resultado un número menos que el inicial:

=FILA(A1)+119

La serie queda 120, 121, 122 y así sucesivamente.

Incrementos distintos de uno.

Para una serie que avance de 10 en 10 y empiece en 570, se multiplica el número de orden por el incremento:

=570+(FILA(A1)-1)*10

El resultado es 570, 580, 590. En general, la fórmula es inicio + (FILA(A1) − 1) × incremento.

Numerar solo las filas que tienen datos.

Cuando la lista tiene filas vacías, lo normal es que la numeración las salte. La función CONTARA cuenta las celdas no vacías de un rango que crece a medida que la fórmula se copia hacia abajo. Si los datos empiezan en A5:

=SI(A5="";"";CONTARA($A$5:A5))

El rango $A$5:A5 tiene la primera celda fija y la última libre, de modo que en la fila 10 se convierte en $A$5:A10 y cuenta los datos que hay hasta allí. La fila vacía queda sin número y la siguiente continúa la serie sin salto. Este uso del signo pesos se explica en el artículo sobre cómo fijar una fórmula en Excel.

Una fórmula como =SI(A5<>"";FILA();"") también deja en blanco las filas vacías, pero no corrige el salto: después de una fila vacía la numeración salta un número.

Consecutivo con prefijo, como en un documento.

Para numerar documentos internos con un formato como FAC-0001, se une el texto con el número formateado con ceros a la izquierda:

=SI(A5="";"";"FAC-"&TEXTO(CONTARA($A$5:A5);"0000"))

Recordemos que una numeración hecha en Excel sirve para control interno, pero no reemplaza la numeración autorizada de la facturación electrónica, que la asigna el sistema de facturación.

Numeración consecutiva condicionada.

Si solo deben numerarse las filas que cumplen una condición, como los vendedores con ventas superiores a 2.000.000, se cuenta cuántas filas la cumplen hasta la actual. Con las ventas en la columna B desde la fila 5:

=SI(B5>2000000;CONTAR.SI($B$5:B5;">2000000");"")

Las filas que no cumplen la condición quedan en blanco y las demás reciben 1, 2, 3, sin saltos. Para otra condición se cambia el criterio, por ejemplo "Bogotá" para contar una ciudad.

Numerar solo las filas visibles al filtrar.

Cuando se aplica un filtro, las fórmulas anteriores siguen contando las filas ocultas. Para que la numeración se rehaga con lo que queda visible, se usa SUBTOTAL con la función 3, que equivale a CONTARA pero ignora las filas ocultas por el filtro:

=SI(A5="";"";SUBTOTAL(3;$A$5:A5))

Así, si se filtran solo los clientes de una ciudad, quedan numerados 1, 2, 3. El uso de los filtros se explica en el artículo sobre para qué sirven los filtros en Excel.

Que la fórmula se copie sola al agregar datos.

Las fórmulas anteriores deben copiarse hacia abajo en todas las filas que se vayan a usar. Para que se agreguen solas, se convierte el rango en una tabla: se selecciona y se presiona Ctrl + T, o se elige «Insertar», «Tabla».

En una tabla, cada vez que se escribe un dato en la fila siguiente a la última, la tabla se amplía y copia la fórmula. Una fórmula de numeración que no depende de la fila en la que empieza la tabla es:

=FILA()-FILA(Tabla1[#Encabezados])

Resta a la fila actual la fila de los encabezados de la tabla, que en este ejemplo se llama Tabla1. Si se inserta una fila encima de la tabla, la numeración no se altera.

Números consecutivos con SECUENCIA en Microsoft 365.

En Excel para Microsoft 365 y Excel 2021 existe SECUENCIA, que genera toda la serie con una sola fórmula. Sus argumentos son el número de filas, el de columnas, el número inicial y el incremento:

=SECUENCIA(10;1;570;10)

La fórmula se escribe en una sola celda y llena hacia abajo diez filas con 570, 580 y así hasta 660. Si alguna de las celdas que debe ocupar tiene datos, muestra el error #¡DESBORDAMIENTO!. En versiones anteriores, la función no existe y se usan las fórmulas con FILA.

Convertir la numeración en valores fijos.

Si la numeración debe quedar fija, por ejemplo porque luego se ordenarán los datos y cada registro debe conservar su número, se copia la columna y se pega sobre sí misma con «Pegado especial», opción «Valores». A partir de ese momento los números no cambian aunque se ordene o se elimine una fila.

Descargar el ejemplo en Excel.

El archivo tiene una hoja con todas las fórmulas del artículo aplicadas a una lista con filas vacías y un filtro activo para probar SUBTOTAL; una hoja con la numeración automática dentro de una tabla, y una con SECUENCIA para Microsoft 365. Descargar archivo.

A continuación respondemos las preguntas frecuentes de nuestros lectores.

• Calculadora de retención en la fuente por salarios
• Guía de propiedad horizontal
• Liquidador de pensiones en Colpensiones
• Liquidador de renta personas naturales
• Liquidador de intereses propiedad horizontal
• Liquidador de intereses judiciales y comerciales