La fórmula para calcular la edad en Excel a partir de la fecha de nacimiento es =SIFECHA(A2;HOY();"y"), que devuelve los años cumplidos. Con la misma función se obtienen los meses y los días adicionales, y con FECHA.MES se calcula la fecha en que una persona cumplirá una edad determinada. ¿Cómo se escribe cada fórmula y qué errores conviene evitar?
Calcular la edad en años cumplidos.
Con la fecha de nacimiento en A2, la edad a la fecha de hoy es:
=SIFECHA(A2;HOY();"y")El argumento "y" indica que se cuentan años completos: la persona cumple un año más solo el día de su cumpleaños. Si nació el 14 de octubre de 1985, el 13 de octubre de 2026 tiene 40 años y al día siguiente, 41.
SIFECHA no aparece en el asistente de funciones de Excel, pero funciona en todas las versiones si se escribe completa. La fecha de nacimiento debe ir primero; si es posterior a la segunda fecha, la función devuelve el error #¡NUM!.
- Guía de propiedad horizontal
- Calculadora de retención en la fuente por salarios
- Proyección y planeación pensional
La edad a una fecha distinta de hoy.
HOY se actualiza cada día, de modo que la edad cambia sola. Si se necesita la edad a una fecha fija, como el 31 de diciembre de un año o la fecha de un contrato, se escribe esa fecha en una celda, por ejemplo B1, y se reemplaza HOY() por $B$1:
=SIFECHA(A2;$B$1;"y")La referencia absoluta permite copiar la fórmula a toda la lista de personas.
Edad en años, meses y días.
Para expresar la edad como «40 años, 11 meses y 29 días», SIFECHA se usa con tres argumentos distintos: "y" para los años, "ym" para los meses que sobran después de los años completos, y los días se calculan restando a la fecha de corte la fecha que resulta de sumar los meses completos a la de nacimiento:
=SIFECHA(A2;B1;"y")&" años, "&SIFECHA(A2;B1;"ym")&" meses y "&(B1-FECHA.MES(A2;SIFECHA(A2;B1;"m")))&" días"SIFECHA tiene también el argumento "md" para los días, pero en algunos casos de fin de mes devuelve resultados incorrectos, por lo que es más seguro calcular los días con FECHA.MES.
La misma lógica sirve para cualquier diferencia entre fechas, como la antigüedad de un trabajador; se explica en el artículo sobre cómo restar fechas en Excel.
Edad en meses y con decimales.
Para algunos cálculos se necesita la edad en meses, como en los niños pequeños, o con decimales, como en estadísticas:
=SIFECHA(A2;B1;"m")=TRUNCAR(FRAC.AÑO(A2;B1;1);2)FRAC.AÑO con el argumento 1 usa los días reales de cada año. Se trunca y no se redondea porque, cerca del cumpleaños, el redondeo mostraría una edad que aún no se ha cumplido: 40,997 años redondeado a dos decimales da 41,00.
Por qué no conviene restar los años.
Una forma frecuente, pero imprecisa, de calcular la edad es restar los años: =AÑO(HOY())-AÑO(A2). Esa fórmula suma un año a todas las personas que aún no han cumplido años en el año en curso. Tampoco es exacto dividir los días entre 365, =(HOY()-A2)/365, porque los años bisiestos acumulan un día cada cuatro años y el resultado cambia un día antes o después del cumpleaños.
Las fórmulas largas que comparan el mes y el día con SI anidados llegan al resultado correcto, pero SIFECHA lo hace en una sola función.
Fecha en que se cumple una edad.
Para saber en qué fecha una persona cumplirá cierta edad, se suman a la fecha de nacimiento los meses equivalentes con FECHA.MES:
=FECHA.MES(A2;12*62)Si una persona nació el 5 de marzo de 1964, cumple 62 años el 5 de marzo de 2026. Este cálculo es útil, por ejemplo, para saber cuándo se cumple la edad de pensión de vejez, que en Colombia es de 57 años para las mujeres y 62 para los hombres. Los requisitos de la pensión se explican en la guía de pensiones.
Para el próximo cumpleaños, se suman a la fecha de nacimiento tantos años como la edad actual más uno: =FECHA.MES(A2;12*(SIFECHA(A2;HOY();"y")+1)). Con las personas nacidas un 29 de febrero, FECHA.MES devuelve el 28 de febrero en los años no bisiestos.
Agrupar las edades en rangos.
Para clasificar una lista de personas por grupos de edad, como menores de 18, de 18 a 29 y de 30 a 44, se arma una tabla con la edad inicial de cada grupo, ordenada de menor a mayor, y se busca con BUSCARV aproximado:
=BUSCARV(C2;$K$2:$L$6;2;VERDADERO)C2 es la edad en años y K2:L6 la tabla de grupos. La función ubica cada edad en el grupo cuyo límite inferior es el mayor que no la supera.
Descargar el ejemplo en Excel.
El archivo calcula para varias personas la edad en años, en años, meses y días, en meses y con decimales, el próximo cumpleaños y el grupo de edad, a una fecha de corte que se puede cambiar. Una segunda hoja calcula la fecha en que se cumple una edad determinada. Descargar archivo.
Preguntas frecuentes.
A continuación respondemos las preguntas frecuentes de nuestros lectores.
¿Cuál es la fórmula para calcular la edad en Excel?
=SIFECHA(A2;HOY();"y"), con la fecha de nacimiento en A2.
¿Cómo calculo la edad en años, meses y días?
Con SIFECHA y los argumentos "y" y "ym" para los años y los meses, y restando FECHA.MES para los días, como en la fórmula del artículo.
¿Por qué la edad me da un año de más?
Porque se restaron los años con AÑO(HOY())-AÑO(A2), que no tiene en cuenta si ya pasó el cumpleaños. SIFECHA lo corrige.
¿Cómo calculo la edad a una fecha determinada?
Reemplazando HOY() por la celda con esa fecha: =SIFECHA(A2;$B$1;"y").
¿Cómo sé en qué fecha alguien cumple 62 años?
Con =FECHA.MES(fecha_de_nacimiento;12*62).
Twitter
Facebook
WhatsApp
LinkedIn