Cómo sacar la frecuencia y el valor que más se repite en Excel

La frecuencia indica cuántas veces aparece un valor, o cuántos valores caen dentro de un intervalo. En Excel se calcula con CONTAR.SI para valores individuales y con la función FRECUENCIA para intervalos, y el valor que más se repite, que en estadística se llama moda, se obtiene con MODA.UNO. ¿Cómo se arma una tabla de frecuencias y qué hacer cuando los datos son textos?

Frecuencia de cada valor con CONTAR.SI.

La forma más sencilla de saber cuántas veces aparece un valor en una lista es CONTAR.SI, que cuenta las celdas de un rango que cumplen un criterio. Supongamos una lista de 15 clientes con su ciudad en A2:A16 y, en C2, la ciudad que queremos contar:

=CONTAR.SI($A$2:$A$16;C2)

Si C2 dice «Bogotá» y seis clientes son de Bogotá, el resultado es 6. Al copiar la fórmula hacia abajo, junto a una lista de las ciudades sin repetir, se obtiene la frecuencia de cada una. El rango lleva signos pesos para que no se desplace.

La lista de valores sin repetir se puede obtener con «Datos», «Quitar duplicados», sobre una copia de la columna, o, en Microsoft 365, con la función UNICOS: =UNICOS(A2:A16).

• Calculadora de retención en la fuente por salarios
• Liquidador de intereses judiciales y comerciales
• Proyección y planeación pensional

Tabla de frecuencias absoluta, relativa y acumulada.

Una tabla de frecuencias completa tiene cuatro columnas, que se calculan a partir de la frecuencia de cada valor:

• Frecuencia absoluta: las veces que aparece el valor, con CONTAR.SI.
• Frecuencia relativa: la proporción sobre el total, =D2/SUMA($D$2:$D$6), con formato de porcentaje.
• Frecuencia acumulada: la suma de las frecuencias hasta esa fila, =SUMA($D$2:D2).
• Frecuencia relativa acumulada: la suma de las relativas hasta esa fila; en la última fila debe dar 100 %.

Con los 15 clientes del ejemplo, la tabla queda así:

Una tabla dinámica produce el mismo resultado sin fórmulas: se arrastra la ciudad al área de filas y otra vez al área de valores, donde Excel la cuenta.

Frecuencia por intervalos con la función FRECUENCIA.

Cuando los datos son números y se quiere saber cuántos caen en cada intervalo, como los resultados de un examen agrupados por rangos, se usa FRECUENCIA. Su sintaxis es:

=FRECUENCIA(datos;grupos)

El argumento datos es el rango con los valores que se cuentan, y grupos, el rango con el límite superior de cada intervalo. Las celdas vacías y los textos se ignoran.

Ejemplo con los resultados de un examen.

Supongamos los resultados 79, 85, 78, 85, 83, 81, 95, 88 y 97 en A2:A10, y los límites 70, 79 y 89 en C2:C4. FRECUENCIA cuenta los valores menores o iguales a cada límite y mayores que el anterior, y agrega un grupo más para los que superan el último límite. Por eso, con tres límites devuelve cuatro resultados:

Entre 71 y 79 hay dos resultados, 78 y 79; entre 80 y 89, cinco, y por encima de 89, dos, 95 y 97.

Cómo se introduce la fórmula.

FRECUENCIA devuelve varios valores a la vez, uno por grupo, de modo que la forma de escribirla depende de la versión:

• En Microsoft 365 y Excel 2021, basta con escribir =FRECUENCIA(A2:A10;C2:C4) en la primera celda y presionar Enter: los resultados se desbordan solos hacia las celdas de abajo.
• En versiones anteriores, primero se selecciona un rango con una celda más que la cantidad de límites, en el ejemplo cuatro celdas, se escribe la fórmula y se presiona Ctrl + Mayús + Enter. Excel la muestra entre llaves {} y la trata como fórmula matricial.

Una alternativa que no requiere fórmulas matriciales es CONTAR.SI.CONJUNTO, con los límites de cada intervalo. Para el grupo de 80 a 89:

=CONTAR.SI.CONJUNTO(A2:A10;">"&C3;A2:A10;"<="&C4)

Da el mismo resultado, 5, y cada celda es independiente de las demás. Con los mismos datos, Excel puede dibujar un histograma desde «Insertar», «Gráfico estadístico», «Histograma».

El valor que más se repite: la moda.

La moda es el valor que aparece más veces en un conjunto de datos. Excel la calcula con MODA.UNO, que reemplaza a la antigua función MODA, aún disponible por compatibilidad:

=MODA.UNO(A2:A11)

Para saber cuántas veces se repite ese valor, se combina con CONTAR.SI: =CONTAR.SI(A2:A11;MODA.UNO(A2:A11)). Si ningún valor se repite, MODA.UNO devuelve el error #N/A.

Cuando hay más de una moda.

Supongamos los valores 3, 7, 7, 2, 9, 7, 3, 5, 3 y 8. El 3 y el 7 aparecen tres veces cada uno. MODA.UNO devuelve solo uno, el 3, porque es el primero que aparece en la lista. Para obtener todos los valores empatados se usa MODA.VARIOS, que devuelve una lista:

=MODA.VARIOS(A2:A11)

En Microsoft 365 se desborda sola; en versiones anteriores se introduce como fórmula matricial en tantas celdas como modas se esperen.

El texto que más se repite.

MODA.UNO solo trabaja con números. Para saber cuál es la ciudad, el producto o el nombre que más se repite, se combinan INDICE, COINCIDIR, MAX y CONTAR.SI:

=INDICE(A2:A16;COINCIDIR(MAX(CONTAR.SI(A2:A16;A2:A16));CONTAR.SI(A2:A16;A2:A16);0))

CONTAR.SI(A2:A16;A2:A16) cuenta cuántas veces aparece cada elemento de la lista; MAX toma el mayor de esos conteos; COINCIDIR encuentra la primera posición que tiene ese conteo, e INDICE devuelve el texto de esa posición. Con la lista de clientes, el resultado es «Bogotá». En versiones anteriores a Microsoft 365 se introduce con Ctrl + Mayús + Enter.

Descargar el ejemplo en Excel.

El archivo tiene tres hojas: «FRECUENCIA», con el ejemplo de los resultados del examen calculado con FRECUENCIA y con CONTAR.SI.CONJUNTO; «Tabla de frecuencias», con las cuatro columnas de frecuencia de una lista de ciudades, y «Valor más repetido», con MODA.UNO, MODA.VARIOS y la fórmula para textos. Descargar archivo.

A continuación respondemos las preguntas frecuentes de nuestros lectores.

• Liquidador de intereses propiedad horizontal
• Guía de arrendamiento sin riesgo
• Guía Laboral 2026
• Liquidador de renta personas naturales
• Guía de propiedad horizontal
• Liquidador de pensiones en Colpensiones