En un extracto bancario o un auxiliar contable es frecuente tener en una sola columna valores positivos, como las entradas, y negativos, como las salidas. Para analizarlos conviene separarlos en dos columnas, sumarlos por aparte o convertir los negativos en positivos. ¿Qué fórmulas se usan para cada cosa?
Separar positivos y negativos en dos columnas.
Supongamos los movimientos de una cuenta bancaria en la columna C, desde la fila 5, con las consignaciones en positivo y los pagos en negativo. En la columna D llevamos las entradas y en la E, las salidas.
Para las entradas, en D5:
=SI(C5>0;C5;"")Si el valor es mayor que cero, la fórmula lo trae; si no, deja la celda vacía. Para las salidas, en E5:
=SI(C5<0;-C5;"")El signo menos delante de C5 convierte la salida en un valor positivo, como se presenta habitualmente en las columnas de débitos y créditos. Si se prefiere conservar el signo negativo, se escribe C5 en lugar de -C5. Ambas fórmulas se copian hacia abajo hasta la última fila.
En el ejemplo, las entradas suman $5.054.200 y las salidas $5.642.750; la diferencia, −$588.550, es el saldo neto de la columna original, lo que sirve como comprobación.
Listar los positivos y los negativos por separado.
En Microsoft 365, FILTRAR extrae en una lista solo los valores que cumplen la condición, sin dejar celdas vacías:
=FILTRAR(C5:C14;C5:C14>0)=FILTRAR(C5:C14;C5:C14<0)Para traer también la fecha y el concepto, el primer argumento se amplía a toda la tabla: =FILTRAR(A5:C14;C5:C14<0). En otras versiones se aplica un «Filtro de número», «Mayor que» 0 o «Menor que» 0, y se copian las filas visibles.
Sumar y contar los positivos y los negativos.
Para sumar o contar sin separar las columnas se usan SUMAR.SI y CONTAR.SI con el operador como criterio:
| Necesidad | Fórmula |
|---|---|
| Suma de los positivos | =SUMAR.SI(C5:C14;">0") |
| Suma de los negativos | =SUMAR.SI(C5:C14;"<0") |
| Cantidad de negativos | =CONTAR.SI(C5:C14;"<0") |
| Suma de los valores sin signo | =SUMAPRODUCTO(ABS(C5:C14)) |
La última suma todos los movimientos como si fueran positivos, útil para conocer el volumen total de la cuenta.
Convertir números negativos en positivos.
La función ABS devuelve el valor absoluto de un número, es decir, el número sin signo:
=ABS(C5)Para −1.200.000 devuelve 1.200.000, y un positivo lo deja igual. Es la forma más segura, porque no cambia el signo de los valores que ya son positivos. Multiplicar por −1 también convierte un negativo en positivo, pero convierte en negativo un positivo; por eso solo se usa cuando todos los valores de la columna son negativos.
Si la operación es una resta cuyo resultado se quiere en positivo, se envuelve completa en ABS: =ABS(25-30) da 5. Escribir =25-30*-1 no sirve, porque Excel multiplica primero: calcula 25 − (−30) y el resultado es 55.
Convertir una columna sin fórmulas.
Para cambiar el signo de una columna completa de negativos, sin columnas auxiliares, se usa «Pegado especial»:
- Escribir -1 en una celda vacía y copiarla.
- Seleccionar los valores negativos.
- Ir a «Inicio», «Pegar», «Pegado especial», elegir «Multiplicar» y aceptar.
- Borrar la celda con -1.
Como el procedimiento multiplica todo lo seleccionado, solo deben seleccionarse los negativos; si se incluyen positivos, quedarán negativos. Para identificarlos antes, puede usarse un filtro.
Mostrar los negativos en rojo o entre paréntesis.
Si solo se quiere distinguir los negativos a simple vista, sin cambiar los valores, basta con el formato de número. En «Formato de celdas», «Número», se marca «Usar separador de miles» y se elige el formato en rojo, o en «Personalizada» se escribe:
#.##0;[Rojo](#.##0)La parte antes del punto y coma se aplica a los positivos, y la de después, a los negativos, que se ven en rojo y entre paréntesis, como en los estados financieros. El valor de la celda sigue siendo negativo para las fórmulas. La función SIGNO, por su parte, devuelve 1 para los positivos, −1 para los negativos y 0 para el cero, útil en fórmulas que dependen del sentido del movimiento.
Descargar el ejemplo en Excel.
El archivo tiene diez movimientos de un extracto bancario con las columnas de entradas y salidas, el valor absoluto y el signo, los totales y las fórmulas de suma y conteo por signo, con una comprobación del saldo neto. Los negativos se muestran en rojo con formato de número. Descargar archivo.
Preguntas frecuentes.
A continuación respondemos las preguntas frecuentes de nuestros lectores.
¿Cómo separo los valores positivos y negativos en dos columnas?
Con =SI(C5>0;C5;"") para los positivos y =SI(C5<0;C5;"") para los negativos.
¿Cómo convierto un número negativo en positivo en Excel?
Con =ABS(celda), que devuelve el valor sin signo.
¿Cómo cambio el signo de toda una columna?
Copiando una celda con -1 y usando «Pegado especial», «Multiplicar» sobre los valores.
¿Cómo sumo solo los negativos?
Con =SUMAR.SI(rango;"<0").
¿Cómo pongo los negativos en rojo?
Con el formato de número #.##0;[Rojo](#.##0), sin cambiar el valor.
Twitter
Facebook
WhatsApp
LinkedIn