Cómo sumar valores por rango de fechas en Excel

Para sumar los valores que están entre dos fechas en Excel se usa SUMAR.SI.CONJUNTO con dos condiciones sobre la columna de fechas: mayor o igual que la fecha inicial y menor o igual que la final. Con la misma función se suman las ventas de un mes o de una fecha específica. ¿Cómo se escriben estas fórmulas y qué errores conviene evitar?

Sumar entre dos fechas con SUMAR.SI.CONJUNTO.

Supongamos una tabla de facturas con la fecha en la columna A, el número de factura en la B y el valor en la C, desde la fila 4 hasta la 27. Necesitamos saber cuánto suman las facturas emitidas entre el 10 de julio y el 22 de agosto de 2026, fechas que escribimos en G4 y G5.

=SUMAR.SI.CONJUNTO(C4:C27;A4:A27;">="&G4;A4:A27;"<="&G5)

El primer argumento es el rango que se suma; luego vienen dos parejas de rango y criterio. La primera exige que la fecha sea mayor o igual que la inicial, y la segunda, que sea menor o igual que la final. El operador va entre comillas y se une a la celda con «&». En el ejemplo, la suma es de $15.700.000, que corresponde a nueve facturas.

Si las fechas no están en celdas, se escriben con la función FECHA para evitar que Excel las confunda por el orden del día y el mes:

=SUMAR.SI.CONJUNTO(C4:C27;A4:A27;">="&FECHA(2026;7;10);A4:A27;"<="&FECHA(2026;8;22))

Todos los rangos deben tener el mismo tamaño. Si el rango que se suma tiene más filas que el de las fechas, la fórmula devuelve #¡VALOR!.

• Proyección y planeación pensional
• Liquidador de renta personas naturales
• Guía de propiedad horizontal

La alternativa con dos SUMAR.SI.

En versiones anteriores a Excel 2007, que no tienen SUMAR.SI.CONJUNTO, se suma todo lo que está desde la fecha inicial y se resta lo que está después de la final:

=SUMAR.SI(A4:A27;">="&G4;C4:C27)-SUMAR.SI(A4:A27;">"&G5;C4:C27)

Es como contar del 15 al 30 en una lista de 1 a 100: se suma del 15 al 100 y se resta del 31 al 100. El resultado es el mismo, pero la fórmula con SUMAR.SI.CONJUNTO es más fácil de leer y de modificar.

Fechas que incluyen la hora.

Si las fechas tienen hora, como 22/08/2026 15:30, la condición «<=22/08/2026» las excluye, porque esa fecha equivale a la medianoche del 22. En ese caso, el límite final se escribe como menor que el día siguiente: "<"&G5+1. Las fechas con hora se explican en el artículo sobre fecha y hora en la misma celda de Excel.

Sumar los valores de una fecha específica.

Para sumar las facturas de un solo día basta con SUMAR.SI, con la fecha en una celda, por ejemplo F9:

=SUMAR.SI(A4:A27;F9;C4:C27)

Como criterio también puede usarse HOY() para sumar lo facturado en el día: =SUMAR.SI(A4:A27;HOY();C4:C27). Para contar las facturas en lugar de sumarlas se usan CONTAR.SI y CONTAR.SI.CONJUNTO con los mismos criterios.

Sumar por mes o por año.

Para sumar las ventas de un mes, se toman como límites el primer día del mes, que se arma con FECHA, y el último, que se obtiene con FIN.MES. Con el mes en F12 y el año en F13:

=SUMAR.SI.CONJUNTO(C4:C27;A4:A27;">="&FECHA(F13;F12;1);A4:A27;"<="&FIN.MES(FECHA(F13;F12;1);0))

Otra forma es SUMAPRODUCTO, que compara el mes y el año de cada fecha:

=SUMAPRODUCTO((MES(A4:A27)=F12)*(AÑO(A4:A27)=F13)*C4:C27)

Ambas dan el mismo resultado, en el ejemplo $12.150.000 para julio de 2026. Para un resumen de todos los meses, la primera fórmula se copia frente a una columna con el primer día de cada mes, o se usa una tabla dinámica con las fechas agrupadas por meses.

Sumar días a una fecha.

Muchas personas que buscan «sumar fechas» necesitan otra cosa: sumar días a una fecha. Como Excel guarda las fechas como números, basta con =A4+30 para obtener la fecha 30 días después, y =FECHA.MES(A4;1) para la del mes siguiente. Para sumar días hábiles se usa DIA.LAB, como se explica en el artículo sobre cómo sumar días laborales a una fecha en Excel, y para calcular los días entre dos fechas, el artículo sobre el cálculo de días entre fechas.

Descargar el ejemplo en Excel.

El archivo tiene 24 facturas ficticias y calcula la suma y el número de facturas entre dos fechas, la comprobación con dos SUMAR.SI, la suma de una fecha específica, la suma de un mes con SUMAR.SI.CONJUNTO y con SUMAPRODUCTO, y un resumen mensual. Descargar archivo.

A continuación respondemos las preguntas frecuentes de nuestros lectores.

• Liquidador de intereses judiciales y comerciales
• Guía Laboral 2026
• Guía de arrendamiento sin riesgo
• Liquidador de intereses propiedad horizontal
• Liquidador de pensiones en Colpensiones
• Calculadora de retención en la fuente por salarios