Cómo unir celdas en Excel sin perder datos

Unir celdas en Excel puede significar dos cosas: juntar el texto de varias celdas en una sola, lo que se hace con fórmulas, o convertir varias celdas en una celda más grande, que es la opción «Combinar y centrar». La diferencia es importante, porque combinar celdas borra el contenido de todas menos la primera. ¿Qué fórmula conviene para cada caso y cómo se combinan celdas sin perder información?

Unir el texto de varias celdas con el operador &.

Supongamos que en las celdas A1 a D1 tenemos «José», «Fernando», «Cuesta» y «Rojas», y queremos el nombre completo en E1. La forma más directa es el operador &, que une textos:

=A1&B1&C1&D1

El resultado es «JoséFernandoCuestaRojas», sin separación. Para que quede un espacio entre cada parte, se agrega " " (un espacio entre comillas) entre las celdas:

=A1&" "&B1&" "&C1&" "&D1

Ahora el resultado es «José Fernando Cuesta Rojas». En lugar del espacio puede usarse cualquier separador: una coma (", "), un guion ("-") o una barra ("/").

El caso particular de los nombres y apellidos, con sus variantes, se desarrolla en el artículo sobre cómo unir nombres y apellidos en Excel.

• Guía de propiedad horizontal
• Guía de arrendamiento sin riesgo
• Proyección y planeación pensional

Las funciones CONCATENAR, CONCAT y UNIRCADENAS.

Excel tiene tres funciones para unir textos. Las tres dan el mismo resultado que el operador &, pero cada una tiene ventajas en ciertos casos.

CONCATENAR.

Es la función tradicional, disponible en todas las versiones. Recibe cada celda o texto como un argumento separado:

=CONCATENAR(A1;" ";B1;" ";C1;" ";D1)

No acepta rangos: si se escribe =CONCATENAR(A1:D1), no une las cuatro celdas. Microsoft la mantiene por compatibilidad, pero recomienda usar CONCAT.

CONCAT.

Disponible desde Excel 2019 y en Microsoft 365, une todas las celdas de un rango:

=CONCAT(A1:D1)

Su limitación es que no agrega separadores: el resultado vuelve a ser «JoséFernandoCuestaRojas».

UNIRCADENAS.

También disponible desde Excel 2019, es la más completa, porque une un rango con el separador que se le indique. Tiene tres argumentos: el separador, si se ignoran las celdas vacías (VERDADERO o FALSO) y el rango:

=UNIRCADENAS(" ";VERDADERO;A1:D1)

Ignorar las celdas vacías evita un problema frecuente. Supongamos que una persona no tiene segundo nombre y B1 está vacía: con el operador & el resultado sería «Ana  Gómez Pérez», con dos espacios seguidos; con UNIRCADENAS, «Ana Gómez Pérez».

UNIRCADENAS también sirve para unir una columna completa en una sola celda, por ejemplo una lista de cuentas separadas por comas:

=UNIRCADENAS(", ";VERDADERO;A1:A20)

Con «Caja», «Bancos» y «Clientes» en la columna, el resultado es «Caja, Bancos, Clientes», sin comas de más por las celdas vacías.

Unir texto con fechas y números.

Cuando una de las celdas tiene una fecha o un número con formato, al unirla con texto se pierde el formato. Supongamos que en A1 está «Factura FE-101», en B1 la fecha 15/10/2026 y en C1 el valor 1.250.000:

=A1&" del "&B1&" por "&C1

El resultado es «Factura FE-101 del 46310 por 1250000», porque Excel guarda las fechas como números de serie y une el valor, no lo que se ve en la celda. Para conservar la presentación se usa la función TEXTO, que convierte el valor en texto con el formato que se le indique:

=A1&" del "&TEXTO(B1;"dd/mm/aaaa")&" por $"&TEXTO(C1;"#.##0")

Ahora el resultado es «Factura FE-101 del 15/10/2026 por $1.250.000».

Los códigos de formato dependen de la configuración regional del equipo. En Excel en español, el año se escribe «aaaa» y, si el separador de miles es el punto, el formato numérico es «#.##0»; en Excel en inglés serían «yyyy» y «#,##0». Para los números, la función DECIMAL evita el problema, porque usa siempre los separadores del equipo: DECIMAL(C1;0) devuelve «1.250.000».

Unir celdas con salto de línea.

Para que cada parte quede en un renglón distinto dentro de la misma celda, como en una dirección, el separador es CARACTER(10), que corresponde al salto de línea:

=A1&CARACTER(10)&B1

Para que el salto se vea, la celda debe tener activada la opción «Ajustar texto», de la pestaña «Inicio». Con UNIRCADENAS también funciona: =UNIRCADENAS(CARACTER(10);VERDADERO;A1:C1).

Combinar celdas con «Combinar y centrar».

La otra forma de unir celdas es la opción «Combinar y centrar», de la pestaña «Inicio», grupo «Alineación». Convierte varias celdas seleccionadas en una sola celda grande, y se usa sobre todo para títulos que abarcan varias columnas.

Esta opción no une los textos. Si varias de las celdas tienen contenido, Excel advierte que solo se conservará el valor de la celda superior izquierda, y los demás se eliminan. Por eso, antes de combinar, conviene unir el contenido con una de las fórmulas anteriores.

El menú de la opción tiene tres variantes:

• Combinar y centrar: une las celdas y centra el contenido.
• Combinar horizontalmente: une las celdas de cada fila por separado, sin combinar las filas entre sí.
• Combinar celdas: une las celdas sin cambiar la alineación.

Para deshacer la combinación se selecciona la celda combinada y se elige «Separar celdas» en el mismo menú. El contenido queda en la primera celda; lo que se borró al combinar no se recupera.

Una alternativa mejor: centrar en la selección.

Las celdas combinadas causan problemas al ordenar, filtrar, copiar y pegar, y al seleccionar columnas. Cuando lo único que se busca es que un título se vea centrado sobre varias columnas, hay una opción que da el mismo aspecto sin combinar:

1. Seleccionar las celdas, por ejemplo A1:D1, con el título escrito en A1.
2. Abrir «Formato de celdas» con Ctrl + 1 y elegir la pestaña «Alineación».
3. En «Horizontal», seleccionar «Centrar en la selección» y aceptar.

El título se ve centrado, pero cada celda sigue siendo independiente.

Convertir el resultado en texto fijo.

El resultado de las fórmulas depende de las celdas originales: si se borran, el texto unido desaparece. Para conservarlo, se copia la columna con las fórmulas y se pega sobre sí misma con «Pegado especial», opción «Valores». Después ya se pueden eliminar las columnas originales.

Para la operación contraria, es decir, dividir el contenido de una celda en varias, se usan las funciones que se explican en el artículo sobre la fórmula para separar texto en Excel.

Descargar el ejemplo en Excel.

El archivo compara el operador &, CONCATENAR, CONCAT y UNIRCADENAS con nombres completos e incompletos, y muestra cómo unir texto con fechas y números, con salto de línea y una columna completa. Una segunda hoja muestra la diferencia entre «Combinar y centrar» y «Centrar en la selección». Descargar archivo.

A continuación respondemos las preguntas frecuentes de nuestros lectores.

• Calculadora de retención en la fuente por salarios
• Guía Laboral 2026
• Liquidador de intereses judiciales y comerciales
• Liquidador de renta personas naturales
• Liquidador de pensiones en Colpensiones
• Liquidador de intereses propiedad horizontal