Cómo calcular las horas trabajadas en Excel

Las horas trabajadas se calculan en Excel restando la hora de entrada de la hora de salida. La resta es sencilla, pero hay tres detalles que suelen dar resultados equivocados: los turnos que pasan la medianoche, los totales de más de 24 horas y la conversión a horas decimales para multiplicar por el valor de la hora. En Colombia, además, el total semanal se compara con la jornada máxima legal, que la ley 2101 de 2021 redujo de forma gradual hasta 42 horas semanales. ¿Cómo se arma la planilla?

Cómo maneja Excel las horas.

Para Excel, una hora es una fracción de un día: las 12:00 del mediodía son 0,5, las 6:00 a. m. son 0,25 y una hora equivale a 1/24. Por eso, al restar dos horas, el resultado también es una fracción de día, que se muestra como hora gracias al formato de la celda.

Las horas pueden escribirse en formato de 24 horas, como 17:30, o con a. m. y p. m., como 5:30 pm, dejando un espacio antes de la abreviatura. Si la celda tiene formato de texto, Excel no las reconoce como horas y la resta da error.

• Calculadora de retención en la fuente por salarios
• Proyección y planeación pensional
• Liquidador de pensiones en Colpensiones

Fórmula para calcular las horas trabajadas.

Con la hora de entrada en B2 y la de salida en C2, la fórmula es:

=C2-B2

Si una persona entra a las 7:00 a. m. y sale a las 4:00 p. m., el resultado es 9:00. La celda del resultado debe tener formato de hora, con el código personalizado h:mm, que se aplica con clic derecho, «Formato de celdas», «Personalizada».

Descontar el tiempo de almuerzo.

Si en D2 se escribe el tiempo de descanso no remunerado, por ejemplo 1:00, se resta también:

=C2-B2-D2

Con el ejemplo anterior, el resultado es 8:00 horas trabajadas.

Turnos que pasan la medianoche.

Si el turno empieza a las 10:00 p. m. y termina a las 6:00 a. m. del día siguiente, la resta da un número negativo, porque 6:00 es menor que 22:00, y Excel muestra la celda llena de numerales (#####). La solución es la función RESIDUO, que devuelve el residuo de dividir entre 1 y convierte el resultado negativo en la fracción de día correcta:

=RESIDUO(C2-B2;1)

El resultado es 8:00. La fórmula sirve también para los turnos normales, de modo que puede usarse en toda la planilla. Con descanso, queda =RESIDUO(C2-B2;1)-D2.

RESIDUO funciona siempre que el turno dure menos de 24 horas. Si un turno puede superar ese tiempo, hay que escribir la fecha junto con la hora de entrada y de salida, por ejemplo 10/10/2026 22:00, y restar directamente.

Sumar las horas de la semana o del mes.

Al sumar las horas diarias con =SUMA(E2:E7), el total puede aparecer equivocado. Supongamos una semana con 49 horas y 15 minutos trabajados: con el formato h:mm, Excel muestra 1:15, porque descuenta los días completos y solo enseña las horas que sobran de 24.

Para que el total muestre todas las horas, la celda debe tener el formato personalizado con la hora entre corchetes:

[h]:mm

Con ese formato el total se ve como 49:15. El valor de la celda es el mismo; lo que cambia es la forma de mostrarlo.

Convertir las horas a número decimal.

Para multiplicar las horas por el valor de la hora o compararlas con la jornada, hay que convertirlas a número, porque 8:30 no es 8,30 sino 8,5 horas. Como Excel guarda las horas como fracción de día, basta con multiplicar por 24:

=E2*24

La celda del resultado debe tener formato de número, no de hora. Con 49:15, el resultado es 49,25. Y para calcular el valor de esas horas, se multiplica por el valor de la hora ordinaria:

=REDONDEAR(F14*D18;0)

Donde F14 son las horas en decimal y D18 el valor de la hora. Este cálculo da el valor de las horas sin recargos.

Comparar con la jornada máxima legal.

La ley 2101 de 2021 redujo la jornada máxima legal de 48 horas semanales de forma gradual: 47 horas desde julio de 2023, 46 desde julio de 2024, 44 desde julio de 2025 y 42 horas semanales desde julio de 2026. Las reglas sobre su distribución se explican en el artículo sobre la jornada máxima legal.

En la planilla, la jornada máxima se escribe en una celda y se compara con el total semanal en decimal:

=MAX(0;F14-D3)

Con 49,25 horas y una jornada de 42, el resultado es 7,25 horas por encima de la jornada. MAX evita un número negativo cuando se trabaja menos. Este resultado sirve como alerta, pero no equivale sin más a las horas extras que deben pagarse: para eso hay que revisar la jornada pactada, cómo se distribuye en la semana y si hay horas nocturnas, dominicales o festivas, que tienen recargos propios.

Para liquidar las horas extras y los recargos con su porcentaje, está la plantilla en Excel para el cálculo de horas extras.

Horas-hombre trabajadas.

Las horas-hombre miden el trabajo total de un grupo: son las horas trabajadas multiplicadas por el número de personas. Se usan para costear proyectos o medir la productividad. Si 12 trabajadores laboran 168 horas en el mes, las horas-hombre son 12 × 168 = 2.016.

Con el número de trabajadores de cada área en B2:B4 y las horas por trabajador en C2:C4, el total es:

=SUMAPRODUCTO(B2:B4;C2:C4)

SUMAPRODUCTO multiplica los trabajadores de cada área por sus horas y suma los resultados, sin necesidad de una columna auxiliar.

Descargar la planilla en Excel.

El archivo tiene una planilla semanal con entrada, salida y descanso, que calcula las horas de cada día con RESIDUO, el total con formato [h]:mm, las horas en decimal, las horas por encima de la jornada que se indique y su valor sin recargos. Incluye un turno nocturno de ejemplo y una hoja de horas-hombre por área. Descargar archivo.

A continuación respondemos las preguntas frecuentes de nuestros lectores.

• Guía de arrendamiento sin riesgo
• Liquidador de renta personas naturales
• Guía de propiedad horizontal
• Guía Laboral 2026
• Liquidador de intereses judiciales y comerciales
• Liquidador de intereses propiedad horizontal