Obtener el nombre o el número del mes de una fecha en Excel

Cuando tenemos una fecha como 18/04/2026, Excel permite extraer el número del mes con la función MES y convertirlo en su nombre con la función TEXTO, sin recurrir a un calendario ni escribir los meses a mano. ¿Qué fórmula usar en cada caso y cómo hacer que el mes salga en español?

Número de cada mes del año.

Antes de entrar en las fórmulas, conviene tener a mano la numeración de los meses, que es la que Excel utiliza internamente para cualquier fecha.

Los meses se numeran del 1 al 12 en el orden del calendario, y cuando la fecha se escribe con dos dígitos, los primeros nueve llevan un cero adelante:

Así, abril es el mes 4, septiembre es el mes 9, el mes 05 es mayo y el mes 11 es noviembre. Esta tabla es también la base de dos de las fórmulas que veremos más adelante.

• Guía de propiedad horizontal
• Proyección y planeación pensional
• Guía Laboral 2026

Cómo sacar el número del mes de una fecha.

La función MES devuelve el número del mes de una fecha, del 1 al 12. Supongamos que en la celda A2 tenemos la fecha 18/04/2026:

=MES(A2)

El resultado es 4, porque abril es el cuarto mes del año.

La función solo trabaja si Excel reconoce el contenido de la celda como fecha. Si la fecha llegó como texto, por ejemplo desde un sistema contable o un archivo descargado, MES devuelve el error #¡VALOR!, y primero hay que convertirla, como explicamos en el artículo sobre qué hacer cuando

Cómo sacar el nombre del mes de una fecha.

El nombre del mes se obtiene de varias formas, y la elección depende de si queremos que el resultado dependa o no de la configuración de idioma del computador.

Con la función TEXTO.

Es la forma más sencilla. La función TEXTO convierte un valor en texto según el formato que le indiquemos, y el código «mmmm» corresponde al nombre completo del mes:

=TEXTO(A2;"mmmm")

Con la fecha 18/04/2026 el resultado es abril. Si solo necesitamos las tres primeras letras, usamos «mmm» y el resultado será «abr».

Los códigos de formato más útiles para trabajar con meses son estos:

Como TEXTO devuelve el nombre en minúscula, si lo necesitamos con mayúscula inicial lo envolvemos en la función NOMPROPIO:

=NOMPROPIO(TEXTO(A2;"mmmm"))

El resultado será «Abril», que es la forma adecuada para encabezados de informes o tablas.

Por qué el mes puede salir en inglés.

TEXTO escribe el nombre del mes en el idioma de la configuración regional de Windows, no en el idioma de Excel. Por eso, si el computador está configurado en inglés, el resultado será «April» aunque Excel esté en español.

Para forzar el español sin cambiar la configuración del equipo, se agrega al formato el código de idioma de Colombia:

=TEXTO(A2;"[$-240A]mmmm")

El código 240A identifica el español de Colombia, de modo que el resultado será «abril» en cualquier computador. Es la opción recomendable cuando el archivo se comparte con otras personas.

Con la función ELEGIR.

Otra alternativa, que no depende en absoluto del idioma, es escribir los doce nombres dentro de la función ELEGIR y dejar que la función MES escoja el que corresponde:

=ELEGIR(MES(A2);"Enero";"Febrero";"Marzo";"Abril";"Mayo";"Junio";"Julio";"Agosto";"Septiembre";"Octubre";"Noviembre";"Diciembre")

La fórmula es más larga, pero tiene una ventaja práctica: el nombre sale exactamente como lo escribimos, de modo que podemos usar mayúsculas, abreviaturas propias o incluso los meses de un año fiscal distinto al calendario.

Con una tabla y BUSCARV.

La tercera opción es construir en otra parte de la hoja una tabla con los números del 1 al 12 y los nombres de los meses al frente, como la del inicio de este artículo, y traer el nombre con la función BUSCARV:

=BUSCARV(MES(A2);$E$2:$F$13;2;0)

Aquí la tabla está en el rango E2:F13, la columna 1 tiene el número y la columna 2 el nombre. El rango va con signos $ para que no se desplace al copiar la fórmula, tema que explicamos en el artículo sobre cómo fijar una fórmula en Excel, y el funcionamiento de la búsqueda se detalla en el artículo sobre la función BUSCARV.

Este método es útil cuando la tabla de meses ya existe en el libro, por ejemplo, en un modelo financiero con una hoja de parámetros.

Convertir el nombre de un mes en su número.

A veces la necesidad es la contraria: tenemos la palabra «abril» en una celda y necesitamos el número 4, por ejemplo, para construir una fecha. En ese caso usamos COINCIDIR sobre la misma tabla de meses:

=COINCIDIR(A2;$F$2:$F$13;0)

La función busca la palabra dentro de la lista de nombres y devuelve su posición, que coincide con el número del mes. El último argumento, cero, exige coincidencia exacta, y la búsqueda no distingue mayúsculas de minúsculas, de modo que «ABRIL» y «abril» dan el mismo resultado.

Mostrar la fecha completa en letras.

Combinando los códigos de formato podemos escribir la fecha completa en texto, por ejemplo «sábado 18 de abril de 2026», algo útil en contratos, certificados o cartas generadas desde Excel:

=TEXTO(A2;"[$-240A]dddd d")&" de "&TEXTO(A2;"[$-240A]mmmm")&" de "&AÑO(A2)

La palabra «de» se agrega fuera del formato, con el operador &, porque dentro de él la «d» significa «día» y la «e» puede interpretarse como año. El año se agrega con la función AÑO para evitar el código del año, que en Excel en español es «aaaa» y en inglés «yyyy», de modo que la fórmula funcione en cualquier versión.

Si lo que necesitamos es el nombre del día, el procedimiento se explica en el artículo sobre cómo obtener el día de la semana en Excel.

Mostrar el mes sin cambiar el contenido de la celda.

Las fórmulas anteriores escriben el mes en otra celda. Si lo único que queremos es que una columna de fechas se vea como «abril» sin dejar de ser fecha, basta con cambiar el formato:

1. Seleccionamos las celdas con las fechas.
2. Damos clic derecho y elegimos «Formato de celdas».
3. En la pestaña «Número» escogemos «Personalizada».
4. En el campo «Tipo» escribimos mmmm y aceptamos.

La diferencia es importante: con el formato la celda sigue conteniendo la fecha completa y se puede usar en cálculos, filtros y tablas dinámicas, mientras que con TEXTO obtenemos un texto que ya no se comporta como fecha.

Descargar el ejemplo en Excel.

El archivo de ejemplo contiene una lista de fechas con el número del mes, el nombre por cada uno de los métodos explicados, la conversión inversa del nombre al número y la fecha completa en letras, de modo que basta con cambiar las fechas de la columna A para ver los resultados. Descargar archivo.

Para otros cálculos con meses, como cuántos meses hay entre dos fechas o cuántos días tiene un mes, consulte los artículos sobre la fórmula para calcular los meses entre fechas y sobre el número de días que tiene un mes.

A continuación respondemos las preguntas frecuentes de nuestros lectores.

• Liquidador de intereses judiciales y comerciales
• Liquidador de pensiones en Colpensiones
• Liquidador de renta personas naturales
• Guía de arrendamiento sin riesgo
• Liquidador de intereses propiedad horizontal
• Calculadora de retención en la fuente por salarios