BUSCARV en Excel: qué es, para qué sirve y ejemplos

BUSCARV es la función de Excel que busca un dato en la primera columna de una tabla y trae el valor que está en la misma fila, en otra columna. Sirve, por ejemplo, para traer el salario de un empleado a partir de su nombre, o el precio de un producto a partir de su código. ¿Cómo se escribe, qué significa cada argumento y por qué a veces devuelve error?

Estructura de la función BUSCARV.

La sintaxis de BUSCARV tiene cuatro argumentos:

=BUSCARV(valor_buscado;matriz_tabla;indicador_columnas;[ordenado])

Cada uno significa lo siguiente:

• Valor buscado: el dato que se busca, como el nombre del empleado. Puede escribirse entre comillas o, mejor, estar en una celda.
• Matriz tabla: el rango donde se busca. El valor buscado debe estar en la primera columna de ese rango.
• Indicador de columnas: el número de la columna del rango de donde se trae el resultado, contando la primera columna como 1.
• Ordenado: FALSO (o 0) para buscar el valor exacto, y VERDADERO (o 1) para una coincidencia aproximada, que exige que la primera columna esté ordenada de menor a mayor.

El último argumento es opcional, pero si se omite Excel asume VERDADERO. Por eso, en casi todos los casos conviene escribir FALSO: con VERDADERO, si el valor no existe, BUSCARV devuelve el de otra fila sin advertirlo.

• Proyección y planeación pensional
• Calculadora de retención en la fuente por salarios
• Liquidador de pensiones en Colpensiones

Ejemplo de BUSCARV.

Supongamos una tabla de empleados en A3:D9, con el nombre en la columna A, la cédula en la B, el cargo en la C y el salario en la D:

Para traer el salario de Laura, con su nombre escrito en G4:

=BUSCARV(G4;$A$4:$D$9;4;FALSO)

Excel busca «Laura» en la columna A, la encuentra en la cuarta fila del rango y devuelve lo que hay en la columna 4 de esa fila: 1.700.000. Con 3 como indicador de columnas devolvería el cargo, «Recepcionista». El rango se fija con signos $ para que no se desplace al copiar la fórmula.

Indicador de columnas automático.

Si se insertan columnas en la tabla, el número de columna escrito en la fórmula deja de corresponder. Para evitarlo, se calcula con COINCIDIR a partir del encabezado:

=BUSCARV(G4;$A$4:$D$9;COINCIDIR("Salario";$A$3:$D$3;0);FALSO)

Así, la fórmula busca siempre la columna llamada «Salario», esté donde esté.

Cuando BUSCARV devuelve error.

Los errores más frecuentes y su causa son estos:

Para mostrar un mensaje en lugar de #N/A cuando el valor no existe se usa SI.ERROR:

=SI.ERROR(BUSCARV(G4;$A$4:$D$9;4;FALSO);"No existe")

Cuando el problema son espacios invisibles, se limpian con ESPACIOS, como se explica en el artículo sobre cómo eliminar espacios en Excel. Y si las cédulas de la tabla son números pero la buscada es texto, se convierte con VALOR: =BUSCARV(VALOR(G9);B4:D9;3;FALSO).

BUSCARV en otra hoja.

La tabla puede estar en otra hoja o en otro libro. Al escribir el segundo argumento se hace clic en la otra hoja y se selecciona el rango, y Excel arma la referencia:

=BUSCARV(A2;Empleados!$A$4:$D$9;4;FALSO)

Si la tabla está en otro libro, la referencia incluye su nombre entre corchetes, como se explica en el artículo sobre cómo vincular celdas en Excel.

Comparar dos listas con BUSCARV.

BUSCARV también sirve para saber qué datos de una lista están en otra. Supongamos una lista de empleados que tomaron vacaciones en A5:A11 y otra de los que tomaron licencia en la columna B. Para saber cuáles de los que tomaron licencia también tomaron vacaciones:

=SI(ESNOD(BUSCARV(B5;$A$5:$A$11;1;FALSO));"No";"Sí")

Si BUSCARV no encuentra el nombre, devuelve #N/A y ESNOD lo convierte en «No». Otras formas de comparar listas se explican en el artículo sobre cómo encontrar valores repetidos en Excel.

BUSCARV hacia la izquierda: INDICE y COINCIDIR.

BUSCARV solo trae valores que están a la derecha de la columna donde busca. Para traer el nombre a partir de la cédula, que está a su derecha, se combinan INDICE y COINCIDIR:

=INDICE($A$4:$A$9;COINCIDIR(G9;$B$4:$B$9;0))

COINCIDIR encuentra la posición de la cédula en la columna B, y INDICE devuelve el nombre que está en esa posición de la columna A. Con la cédula 64.357.671, el resultado es «Mónica». Esta combinación funciona en cualquier dirección y no se afecta si se insertan columnas.

BUSCARX en Microsoft 365.

En Microsoft 365 y Excel 2021, BUSCARX reemplaza a BUSCARV: busca en cualquier dirección, busca por defecto el valor exacto y tiene un argumento para cuando no encuentra el dato:

=BUSCARX(G9;$B$4:$B$9;$A$4:$A$9;"No existe")

Los argumentos son el valor buscado, el rango donde se busca, el rango de donde se trae el resultado y el texto si no lo encuentra.

BUSCARV con dos criterios.

Cuando el dato depende de dos condiciones, como el nombre y la cédula, se crea una columna auxiliar que una ambos valores con «&» y se busca la combinación. Este caso, junto con BUSCARV dentro de SI y las alternativas sin columna auxiliar, se explica en detalle en el artículo sobre BUSCARV con condiciones y con dos criterios. Y para buscar un valor dentro de rangos, como una tabla de comisiones, se usa la coincidencia aproximada, como en la tabla de comisiones por ventas en Excel.

Descargar los ejemplos de BUSCARV.

El archivo tiene tres hojas: «BUSCARV», con la tabla de empleados y las fórmulas del artículo, incluidas la columna automática, SI.ERROR, INDICE y COINCIDIR; «Comparar listas», con las listas de vacaciones y licencias; y «BUSCARX (365)». Descargar archivo.

A continuación respondemos las preguntas frecuentes de nuestros lectores.

• Guía de arrendamiento sin riesgo
• Liquidador de intereses propiedad horizontal
• Liquidador de intereses judiciales y comerciales
• Liquidador de renta personas naturales
• Guía Laboral 2026
• Guía de propiedad horizontal